Skip to content

19F R1

Version: 0.1.2 • Status: 🔬 beta • Last Modified: 2025-12-04

Description

1D 19F R1 measurement

  • with optional 1H decoupling (use -DHDEC flag)
  • tested with Topspin 3.7.0

Experiment Type

relaxation 1d

Features

  • R1
  • inversion_recovery
  • broadband

Authors

Additional Fields

Field Value
File Name 19f_r1.cw
File Path sequences/19f_r1.cw
Git History {hash: 0dc713d7, date: 2025-12-04, author: Chris Waudby, email: c.waudby@ucl.ac.uk, message: update modified date}
{hash: cc8e1d92, date: 2025-12-04, author: Chris Waudby, email: c.waudby@ucl.ac.uk, message: fix and test 19f_r1.cw (TS37)}
{hash: d3999499, date: 2025-11-19, author: chriswaudby, email: cwaudby@gmail.com, message: fix looping}
{hash: 240094c6, date: 2025-11-19, author: chriswaudby, email: cwaudby@gmail.com, message: fix - correct looping}
{hash: e23a105b, date: 2025-11-16, author: chriswaudby, email: cwaudby@gmail.com, message: rename pulse to duration for reference pulse consistency}
{hash: 15d53f5b, date: 2025-11-16, author: chriswaudby, email: cwaudby@gmail.com, message: update experiment filenames}
{hash: c78ec494, date: 2025-11-16, author: chriswaudby, email: cwaudby@gmail.com, message: Update pulse sequence metadata and documentation}
{hash: 1018f450, date: 2025-09-30, author: chriswaudby, email: cwaudby@gmail.com, message: Add new sequences for 19F R1, R2, and perfect echo measurements; update schema fields and documentation}
Acquisition Order f1
relaxation.duration
Dimensions relaxation.duration
f1
Reference Pulse {channel: f1, duration: p1, power: pl1}
{channel: f2, duration: p3, power: pl2}
Relaxation {type: R1, model: inversion_recovery, channel: f1, duration: t1delay}
Typical Nuclei 19F
1H

Created: 2024-05-21 Repository: github.com/waudbygroup/pulseprograms Schema version: 0.0.2

Source Code

View on GitHub: github.com/waudbygroup/pulseprograms/sequences/19f_r1.cw

;@ schema_version: "0.0.2"
;@ sequence_version: "0.1.2"
;@ title: 19F R1
;@ description: |
;@   1D 19F R1 measurement
;@
;@   - with optional 1H decoupling (use -DHDEC flag)
;@   - tested with Topspin 3.7.0
;@ authors:
;@   - Chris Waudby <c.waudby@ucl.ac.uk>
;@ created: 2024-05-21
;@ last_modified: 2025-12-04
;@ repository: github.com/waudbygroup/pulseprograms
;@ status: beta
;@ experiment_type: [relaxation, 1d]
;@ features: [R1, inversion_recovery, broadband]
;@ typical_nuclei: [19F, 1H]
;@ dimensions: [relaxation.duration, f1]
;@ acquisition_order: [f1, relaxation.duration]
;@ reference_pulse:
;@ - {channel: f1, duration: p1, power: pl1}
;@ - {channel: f2, duration: p3, power: pl2}
;@ relaxation: {type: R1, model: inversion_recovery, channel: f1, duration: t1delay}


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

define list<delay> t1delay = <$VDLIST>

"d11=30m"
"d12=20u"

"l1=0"

; calculate 5kHz purge pulse
"p11=50u"
"plw11=plw1*pow(p1/p11,2)"

"p2=p1*2"

; for baseopt
"acqt0=-p1*2/3.1416"

"DELTA=1m"

1 ze 
#ifdef HDEC
  d11 pl12:f2
2 30m do:f2
#else
  d11
2 30m
#endif /* HDEC */

  "DELTA=t1delay[l1]-p16-d16-4u"

  ; purge
  20u pl11:f1
  (2mp ph11):f1
  20u
  (3mp ph12):f1

  d1
  4u UNBLKGRAD
  4u pl1:f1

  p2 ph1     ; 180
  p16:gp1
  d16
  4u BLKGRAD
  DELTA

  p1 ph2     ; 90

#ifdef HDEC
  go=2 ph31 cpd2:f2
  d11 do:f2 mc #0 to 2 
     F1QF(calclc(l1, 1))
#else
  go=2 ph31 
  d11 mc #0 to 2 
     F1QF(calclc(l1, 1))
#endif /* HDEC */

exit 


ph1 = 0 1 2 3
ph2 = 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph31= 0 0 0 0 1 1 1 1 2 2 2 2 3 3 3 3
ph11=0
ph12=1

;pl1: f1 channel - power level for pulse (default)
;pl11: f1 channel - 5 kHz purge pulse
;pl12: f2 channel - power level for CPD/BB decoupling
;p1 : f1 channel -  90 degree high power pulse
;p2 : f1 channel - 180 degree high power pulse
;p16: homospoil/gradient pulse                       [1 msec]
;d1 : relaxation delay (excluding saturation time)
;d11: delay for disk I/O                             [30 msec]
;d12: delay for power switching                      [20 usec]
;d16: delay for homospoil/gradient recovery
;cpd2: decoupling according to sequence defined by cpdprg2
;pcpd2: f2 channel - 90 degree pulse for decoupling sequence
;ns: 4 * n
;ds: 4


;for z-only gradients:
;gpz1: 41%

;use gradient files:   
;gpnam1: SMSQ10.100

Changelog

  • 2025-12-04 (0dc713d7): update modified date - Chris Waudby
  • 2025-12-04 (cc8e1d92): fix and test 19f_r1.cw (TS37) - Chris Waudby
  • 2025-11-19 (d3999499): fix looping - chriswaudby
  • 2025-11-19 (240094c6): fix - correct looping - chriswaudby
  • 2025-11-16 (e23a105b): rename pulse to duration for reference pulse consistency - chriswaudby
  • 2025-11-16 (15d53f5b): update experiment filenames - chriswaudby
  • 2025-11-16 (c78ec494): Update pulse sequence metadata and documentation - chriswaudby
  • 2025-09-30 (1018f450): Add new sequences for 19F R1, R2, and perfect echo measurements; update schema fields and documentation - chriswaudby